Bdtyktl

This code sets a pin HIGH for 1 microsecond and then LOW for 1 microsecond. The expected frequency should be about 500 kHz. When measuring the output the frequency is about 96.4khz. Why ?

int del = 1;



void setup() {

   // put your setup code here, to run once:

pinMode(3, OUTPUT);

}



void loop() {

  // put your main code here, to run repeatedly:



digitalWrite(3, HIGH);

delayMicroseconds(del);

digitalWrite(3, LOW);

delayMicroseconds(del);



}

Welcome to SE.

digitalWrite() takes a few microseconds to execute as well. There is also some overhead around the delayMicroseconds() function.

I you need exactly 500 kHz, you would want to consider using a timer.
You can read up on how to set one up in the microcontrollers datasheet.

Unfortunately, I don't have access to an Arduino Leonardo, but here is an example code for the ATmega328P. The register names will be different, but you should be able to adapt the code to fit your Arduino.

// 500 kHz frequency



void setup() {

  cli();                 //Disable interrupt during setup

  TCCR2A = 0;

  TCCR2B = 0;



  TCCR2B |= (1 << CS20); //Enable timer without prescaler

  OCR2A = 15;            //Do interrupt TIMER2_COMPA after reaching this counter value

  TIMSK2 |= (1 << 1);    //Enable TIMER2_COMPA interrupt



  DDRD |= (1 << PORTD3); //Set Digital Pin 3 as Output Pin

  sei();                 //Enable interrupts again

}



ISR(TIMER2_COMPA_vect) { //If the counter has reached the point where the output needs to be low

  TCNT2 = 0;

  PIND |= (1 << PORTD3); //Toggle Digital Pin 3

}



void loop() {

  //your looping code here

}

Explanation:
TIMER2 is an 8-bit timer, which means it will always count from 0 to 255, regardless of what the CPU is doing.

Normally, it counts up at the Arduino's clock frequency, like 16 MHz.

When the counter hits 15, a special code is immediately executed, called an "Interrupt Service Routine". In this code, we reset the timer and change the state of your outpin pin, resulting in a 500 kHz square wave on that pin.

We count to 15 since there are 16 steps in between "0" where the counter begins and 15, where we reset it.

16'000'000 Hz / 1 (no prescaler) / 16 (counter) / 2 = 500 kHz

The divisor of 2 comes from the fact that we need to change the pin state twice for every full square of the output signal.

delayMicroseconds() has a minimum lower value of 3-4 us per the IDE documentation. It won't do 1.

loop() also adds some delay mechanisms doing it's background stuff.

You will see better results with a while() :

loop(){

  while (1){

  digitalWrite(3, HIGH);

  delayMicroseconds(del);

  digitalWrite(3, LOW);

  delayMicroseconds(del);

  }

}

with direct port manipulation in place of the digital writes.

There will also be jitter from the millis() background time keeping, if you want a smoother signal it will be best to turn off interrupts as well.