Bdtyktl

I pass the following to a function:

{#a, #b, #c} &

These are keys that are used in a list of associations.
There are instances where I want to pass only the last 2 elements, such as:

{#b, #c} &

Right now, I just rewrite it. But it seems like there should be a way to do this by getting rid of the first slot.

I looked at the full form and see that it's:

FullForm[{#a, #b, #c} &]

Function[List[Slot["a"], Slot["b"], Slot["c"]]]

I thought I could somehow get inside and drop Slot["a"], but can't seem to do it. I tried replacing Slot["a"] with a blank, but I'm left with a comma at the beginning of the list. I also tried Apply to change Function to List and doing it in the result. I couldn't.

Is there any way to get rid of the first element, #a, without rewriting the expression?

You could pass it to Delete:

Delete[#, {1, 1}] &[{#a, #b, #c} &]

{#b, #c} &

foo = {#a, #b, #c} &;



foo[[{1}, 2 ;;]]

{#b, #c} &

or, but only because we know there won't be any side effects:

Evaluate /@ Rest /@ foo 

{#b, #c} &

or

foo /. {_Slot, rest__Slot} :> {rest}

At the end consider using an operator form of a KeyDrop

bar = KeyTake[{"a", "b", "c"}];



(Rest /@ bar)@<|"a" -> 1, "b" -> 1, "c" -> 1|>

<|"b" -> 1, "c" -> 1|>