Bdtyktl

Using Word 2016 (and apparently 2013, and 365), there is no longer an option for showing a page's text boundaries. Rather it defaults to essentially paragraph boundaries. How can I get my page's text boundaries (i.e. margins) displayed again?

According to this site and this site Microsoft, in their infinite wisdom, has declared this beloved, long-standing feature a bug, and fixed it in their recent editions (with no apparent intention of returning).

You can visit here to try and convince Microsoft to correct this egregious offense.

And no Google, the page margins/text boundaries are not the same as the guides/rulers.

One possible work-around, using grid lines:

1. Layout > Align > Grid Settings


2. 
   

   Set grid settings (assuming 8 1/2" x 11" paper with 1" margins):

   
   
   
   
   
   • Horizontal spacing 6.5"
   
   
   • Vertical spacing 8.99"
   
   
   • Check Display gridlines on screen
   
   
   • Vertical every 1
   
   
   • Horizontal every 1
   
   
   
   



3. Click OK

Here is my macro lifehack that makes use of the gridlines to display text boundaries in the pre-2013 style. The macro switches boundaries on/off.

The produced boundaries are a bit improved: they extend at the full page width and height, crossing in the corners. If you like boundaries that look just like a rectangle, like it was in Office before 2013, remove ' at the start of this line:

' ActiveDocument.GridOriginFromMargin = True

Downside: There will be the same boundaries for the whole document, so if you have multiple sections with different size margins, their boundaries will be like those of the section that is current at the moment when you run the macro.

The macro:

Sub view_page_boundaries()

' provide page boundaries using a customised page grid

    With Selection

        ActiveDocument.GridOriginFromMargin = False

        ' uncomment to have page boundaries like standard for pre-2013

        ' ActiveDocument.GridOriginFromMargin = True

        If ActiveDocument.GridOriginFromMargin = False Then

            ' display crossing boundaries at full width and height

            ActiveDocument.GridDistanceHorizontal = .PageSetup.PageWidth - .PageSetup.LeftMargin - .PageSetup.Gutter - .PageSetup.RightMargin

            ActiveDocument.GridDistanceVertical = .PageSetup.PageHeight - .PageSetup.TopMargin - .PageSetup.BottomMargin

        Else

            ' display boundaries like those in pre-2013

            ' 0.05 is half-millimeter to prevent cutting off the right and bottom boundaries by the margins

            ActiveDocument.GridDistanceHorizontal = CentimetersToPoints(Round(PointsToCentimeters( _

            .PageSetup.PageWidth - .PageSetup.LeftMargin - .PageSetup.Gutter - .PageSetup.RightMargin), 1) - 0.05)

            ActiveDocument.GridDistanceVertical = CentimetersToPoints(Round(PointsToCentimeters( _

            .PageSetup.PageHeight - .PageSetup.TopMargin - .PageSetup.BottomMargin), 1) - 0.05)

            ActiveDocument.GridOriginHorizontal = .PageSetup.LeftMargin + .PageSetup.Gutter

            ActiveDocument.GridOriginVertical = .PageSetup.TopMargin

        End If

        If Options.DisplayGridLines = False Then

            Options.DisplayGridLines = True

            ' do not need cropmarks at all with crossing boundaries

            ActiveWindow.View.ShowCropMarks = False

            ActiveDocument.GridSpaceBetweenHorizontalLines = 1

            ActiveDocument.GridSpaceBetweenVerticalLines = 1

        Else

            ActiveDocument.GridOriginFromMargin = True

            ' display cropmarks when there are no boundaries

            ActiveWindow.View.ShowCropMarks = True

            ActiveDocument.GridSpaceBetweenHorizontalLines = 2

            ActiveDocument.GridSpaceBetweenVerticalLines = 2

            ActiveDocument.GridDistanceHorizontal = CentimetersToPoints(0.18)

            ActiveDocument.GridDistanceVertical = CentimetersToPoints(0.32)

        End If

    End With

End Sub

Thanks to bagwell005, I found a variation that works for my purposes. I went to File>Options>Advanced. Under "Show document content" I selected "Show crop marks." IMHO, this provides a workable sense of the margins. I hope it helps!

text boundaries are located here--> File>Options>Advanced..scroll down a bit to "Show document content" Simply check the "Show text boundaries" and enjoy the mess, they're not the same as previous versions of Word :(